AUTOEXEC.BAT

AUTOEXEC.BAT 是一个由 MS-DOS 自动在启动的时候执行的批处理文件，所以你可以把你想
让你的计算机在启动的时候执行的命令放在 AUTOEXEC.BAT 文件里面。

通常，在老版本的 MS-DOS（比 MS-DOS 6.0 要老）里面，MS-DOS 的命令提示符默认是 
$N$G。在 MS-DOS 6.0 或更高版本里面，默认的提示符是 $P$G。你可以在 AUTOEXEC.BAT 
文件中加一条 PROMPT 命令以便让计算机在启动时自动设置 MS-DOS 提示符。

如果你的启动的磁盘（比如 C 盘）里面没有 AUTOEXEC.BAT 文件，MS-DOS 会在计算机启动
时询问日期和时间。如果你的启动的磁盘上有 AUTOEXEC.BAT，MS-DOS 就将执行 
AUTOEXEC.BAT 文件中的命令而不是询问日期和时间。

你可以使用 AUTOEXEC.BAT 文件加载常驻内存程序。同样，你也可以用 AUTOEXEC.BAT 来
运行初始化程序。

如果你使用常驻内存程序，你应该优化内存的使用。要做这件事，在你的 CONFIG.SYS 
文件中使用扩展内存管理程序和扩充内存管理程序，并在你的 AUTOEXEC.BAT 文件中使用 
LH 命令。

要优化磁盘性能，你可以在你的 AUTOEXEC.BAT 文件中运行 SMARTDRV.EXE 程序。要访问
光盘驱动器，你可以在你的 AUTOEXEC.BAT 文件中运行 MSCDEX.EXE 程序，同时在 
CONFIG.SYS 中加载一个光盘驱动器的设备驱动程序。通常，你可以在网上找到一个通用的
ATAPI 光盘驱动器的驱动程序：IDE.SYS。要进行这样一个设置，在你的 CONFIG.SYS 文件
中加入“DEVICE=IDE.SYS /D:MSCD000”，并在你的 AUTOEXEC.BAT 文件中加入
“MSCDEX.EXE /D:MSCD000”。

有一些其他的选项可以用来加速你的工作。你可以加“SET DIRCMD=/P/O”命令来让 MS-DOS 
在你打 DIR 命令的时候自动使用 /P/O 开关。同样，如果你想用 Ctrl+C 组合键在有任意
输入/输出操作的时候中断一个程序，你可以加“BREAK=ON”命令（默认情况下，CTRL+C 只
在输出到显示器或者从键盘输入的时候起作用）。

你可以在这里看到一个视窗千禧版启动盘上的 AUTOEXEC.BAT 文件的一个副本：

-------- AUTOEXEC.BAT --------
@ECHO OFF
path=c:\windows;c:\windows\command
\hibinv.exe
call \checksr.bat
IF "%config%"=="QUICK" GOTO QUICK
set EXPAND=YES
SET DIRCMD=/O:N
set LglDrv=27 * 26 Z 25 Y 24 X 23 W 22 V 21 U 20 T 19 S 18 R 17 Q 16 P 15
set LglDrv=%LglDrv% O 14 N 13 M 12 L 11 K 10 J 9 I 8 H 7 G 6 F 5 E 4 D 3 C
cls
call setramd.bat %LglDrv%
set temp=c:\
set tmp=c:\
path=%RAMD%:\;a:\;%path%;%CDROM%:\
copy command.com %RAMD%:\ > NUL
set comspec=%RAMD%:\command.com
copy extract.exe %RAMD%:\ > NUL
copy readme.txt %RAMD%:\ > NUL

:ERROR
IF EXIST ebd.cab GOTO EXT
echo Please insert Windows Millennium Edition Startup Disk 2
echo.
pause
GOTO ERROR

:EXT
%RAMD%:\extract /y /e /l %RAMD%: ebd.cab > NUL
echo The diagnostic tools were successfully loaded to drive %RAMD%.
echo.

IF "%config%"=="NOCD" GOTO QUIT
IF "%config%"=="HELP" GOTO HELP
LH %ramd%:\MSCDEX.EXE /D:mscd001 /L:%CDROM%
::If MSCDEX doesn't find a drive...
IF ERRORLEVEL 1 SET CDPROB=1
::
GOTO QUIT

:HELP
LH %ramd%:\MSCDEX.EXE /D:mscd001 /L:%CDROM%
::If MSCDEX doesn't find a drive...
IF ERRORLEVEL 1 SET CDPROB=1
cls
call help.bat
::
GOTO QUIT

:QUIT
call fixit.bat
rem clean up environment variables
set CDPROB=
set CDROM=
set LglDrv=
GOTO QUICK

:QUICK
-------- End of the file --------

而这里是 SETRAMD.BAT 文件。

-------- SETRAMD.BAT --------
@echo off
set RAMD=
set CDROM=

echo.
echo Preparing to start your computer.
echo This may take a few minutes. Please wait...
echo.

a:\findramd

if errorlevel 255 goto no_ramdrive

if not errorlevel 3 goto no_ramdrive

goto do_shift

:loop
if errorlevel %1 goto no_shift

:do_shift
set cdrom=%2
shift
shift
if not %1*==* goto loop
goto no_ramdrive

:no_shift
set ramd=%2

if "%RAMD%"=="C" goto c_drive

goto success

:c_drive
echo Windows Millennium Edition has detected that drive C does not contain a valid
echo FAT or FAT32 partition. There are several possible causes.
echo.
echo 1.  The drive may need to be partitioned. To create a partition on the drive, 
echo run FDISK from the MS-DOS command prompt. 
echo.
echo 2.  You may be using third-party disk-partitioning software. If you are using 
echo this type of software, remove the Emergency Boot Disk and restart your 
echo computer. Then, follow the on-screen instructions to start your computer from 
echo a floppy disk.
echo .
echo 3.  Some viruses also cause your drive C to not register. You can use a virus 
echo scanning program to check your computer for viruses.
echo.
goto success

:no_ramdrive
echo The Windows Millennium Edition startup disk could not create a temporary drive
echo for the diagnostic tools. This may be because this computer has less than the
echo minimum required extended memory.
echo.
:success
-------- End of the file --------